良玉的博客 点点滴滴,积水成河_良玉的博客_页游、手游linux运维工程师之路

Linux之sed匹配第N个进行替换

文本:
aa
88
bb
88
88
cc
88
88


替换第一个88为--:
  1. sed '0,/88/s//--/' file


  2. sed ':a;N;$!ba;s/88/--/' file

[解析]
这有两种方法,第一个是只匹配到第一个88为止,然后替换那个88为--。
第二个句子是通过循环把文本全部读进pattern space 然后只替换第一个。


替换第N[3]个88为--:
  1. #替换第三个

  2. sed '/88/{x;s/^/./;/^\.\{3\}$/{x;s/.*/--/;x};x;}' file


  3. sed ':a;N;$!ba;s/88/--/3' file

[解析]
第一个命令叫打点记数法,因为sed没有 var++ 之类的操作来记数。
第二个命令上面第一个其实是一样的原理,全部读入文本后统一替换第3个匹配的内容。


替换最后一个匹配的88为--:
  1. sed ':a;/\n88/!{$s/88/--/;N;ba};P;D' file


  2. sed ':a;N;$!ba;s/\(.*\)88/\1--/' file

[解析]
第一个命令,没匹配到 /\n88/ 的内容就读取下一行,然后 ba 跳转去开始处,如果读取到88的行呢,就执行后面的 P;D 组合,D也有循环功能,一直把匹配 \n88 内容的第一行打印,删除,直到不匹配/\n88/(因为换行符已经被打印出去了,所以不再会匹配到 \n88),这时候才继续往下读,如果又读到88的行,那么又执行P;D循环,同上操作。一直到匹配到最后一个88的行,继续读取到末行时执行替换,N 因为没有下一行可读,所以会自动中止命令,因为没有 -n 参数会打印 pattern space 里的内容到屏幕,所以就不会再执行后面的 ba 避免了死循环,这样的用法只存在于 GNU sed ,大家注意。所以这整个流程只会替换最后一个88。
第二个命令其实和上面的都一样,也是全部读进 pattern space 里,最后利用正则的贪婪替换掉最后一个88。


标签: linuxsedsed匹配第N个进行替换

作者:良玉 分类:Shell 浏览:10655 评论:2
留言列表
刺猬
刺猬 很棒,解决了我的大问题,我转载下文章,注明出处,谢谢!  回复
良玉
良玉 客气客气  回复
发表评论
来宾的头像